log info "Starting Automatic Backup Script"

# months array
:local months ("jan","feb","mar","apr","may","jun","jul","aug","sep","oct","nov","dec");
# get time
:local ts [/system clock get time]
:set ts ([:pick $ts 0 2]."-".[:pick $ts 3 5])
# get Date
:local ds [/system clock get date]
# convert name of month to number
:local month [ :pick $ds 0 3 ];
:local mm ([ :find $months $month -1 ] + 1);
:if ($mm < 10) do={ :set mm ("0" . $mm); }
# set $ds to format YYYY-MM-DD
:set ds ([:pick $ds 7 11] .".". $mm . "." . [:pick $ds 4 6])

:local backupfilename ($ds."_".$ts)

:local ftpusername "ftp"

:local ftpuserpassword "123ftp"

:local ftphostname "192.168.0.14"

:local backuppath ("/bak/conf/mt/".[/system identity get name])

/system backup save name="$backupfilename"

:delay 3s

/export compact file="$backupfilename"

:log info "Please wait..."

:delay 3s

:log info "Sending Backup Mikrotik to FTP Server..."

/tool fetch address="$ftphostname" src-path="$backupfilename.backup" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="$backuppath./$backupfilename.backup"

:delay 3s

/tool fetch address="$ftphostname" src-path="$backupfilename.rsc" user="$ftpusername" password="$ftpuserpassword" port=21 upload=yes mode=ftp dst-path="$backuppath./$backupfilename.rsc"

:delay 3s

:log info "Removing backup files from Mikrotik"

/file remove "$backupfilename.backup"

/file remove "$backupfilename.rsc"

:log info "Finished Backup Script"